coord-transf.2d elements3d elementsnon geo scriptsfunctionscontrol statem.attributesvariousaddons
planarprimitivebasic shapesprismscomplex shapesfrom polylines3d cuttingsolid commandsvarious
TEXT RICHTEXT LIGHT PICTURE BINARY HOTSPOT
Name
RICHTEXT
Syntax
RICHTEXTx, y, height, 0, textblockname
Aufklappen Range
x, Typ Real
y, Typ Real
height, Typ Real
textblockname, Gültiger Name eines Textblocks

[bis ArchiCAD® 9 ist der 4. Parameter immer 0]
Aufklappen Description
Gibt vom Punkt (x/y) ausgehend einen zuvor definierten TEXTBLOCK aus. Die Buchstaben werden in einzelne polygonale Prismen mit der Grundfläche in der X/Y-Ebene und der Stärke height in Z-Richtung erzeugt.

Im Gegensatz zum TEXT-Befehl, der relativ einfach Ausdrücke in 3D-Text umwandelt, ist RICHTEXT der letzte einer Befehlskette, die komplex formatierten Text erlaubt.
Aufklappen Example
! ### Definition der Zeichensätze
Zeichensatz="Courier New"
schrifthoehe=2.5

DEFINE STYLE{2} "TypA" "Arial", schrifthoehe, 0
DEFINE STYLE{2} "TypN" Zeichensatz, schrifthoehe, 0
DEFINE STYLE{2} "TypF" Zeichensatz, schrifthoehe, 1
DEFINE STYLE{2} "TypH" Zeichensatz, schrifthoehe, 32


! ### Definition der zusammenhängenden Texte

PARAGRAPH "Titel" 4,
  5, 2, 2, 1
  PEN 1
  SET STYLE "TypA"
  "Dies ist ein Beispiel für eine Wohnungsliste, "
  "die nun einfach mit echten Exponenten in den "
  "Einheiten darstellbar ist."
  "\nIm Fließtext, der pro Einzelstring nicht mehr "
  "als 255 Zeichen lang sein darf, können einige "
  "Sonderzeichen gesetzt werden:"
  PEN 2
  "\n\\n"
  PEN 1
  ": Zeilenumbruch"
  PEN 2
  "\n\\t"
  PEN 1
  ": Tabulator"
  PEN 2
  "\n\\"
  PEN 1
  ": Backslash"
  "\nWie man sieht ist auch ein freier Wechsel der "
  "Farben innerhalb eines Textes kein Problem mehr "
  "und bedarf nicht der langwierigen Breitenberech"
  "nung und Positionierung von Einzeltexten."
  "\nSilbentrennung ist aber noch nicht enthalten. ;-)"
  ENDPARAGRAPH


PARAGRAPH "Kopf" 1,
  25, 5, 0, 1.5,
  50
  PEN 3
  SET STYLE "TypF"
  "\nRAUM\tFLÄCHE"
  ENDPARAGRAPH

PARAGRAPH "Wohnen" 1,
  25, 5, 0, 1.5,
  50
  PEN 1
  SET STYLE "TypN"
  "Wohnen"
  "\t" + STR(27.5,5,2) + " m"
  SET STYLE "TypH"
  "2"
  ENDPARAGRAPH

PARAGRAPH "Essen" 1,
  25, 5, 0, 1.5,
  50
  PEN 1
  SET STYLE "TypN"
  "Essen"
  "\t" + STR(9.3,5,2) + " m"
  SET STYLE "TypH"
  "2"
  ENDPARAGRAPH

PARAGRAPH "Summe" 1,
  25, 5, 0, 1.5,
  50
  PEN 1
  SET STYLE "TypF"
  "\t--------"
  "\nSumme:"
  "\t" + STR(27.5+9.3,5,2) + " m"
  SET STYLE "TypH"
  "2"
  ENDPARAGRAPH

! ### Ausgabetexte festlegen.
bezug = 0
TEXTBLOCK "Ausgabe" 90, 1, 0,
  1, 1, bezug,
  "Titel","Kopf","Wohnen","Essen","Summe"

! ### Ausgabe

PEN SYMB_VIEW_PEN

RICHTEXT 0,0, 0.1,0,"Ausgabe"
Aufklappen Specialities
Einen Befehl für rein zweidimensionalen Text für den 3D-Raum gibt es in GDL nicht.

Sind die Textbestandteile in TEXTBLOCK nicht mit PARAGRAPH definiert, sondern als Klartexte, so sind diesen (nur diesen) Teilen noch keine Attribute zugewiesen worden. Auf diese Bestandteile wirken sich dann die zur Ausführung von RICHTEXT gesetzten Attribute aus.
Aufklappen Attributes
PEN, STYLE, MATERIAL
Aufklappen Context
3D-Skript
Aufklappen ArchiCAD®
since 9.0
Aufklappen References
GDL-Handbuch 9.0 (DE) p. 97
GDL-Handbuch 10.0 (DE) p. 93
GDL-Handbuch 11.0 (DE) p. 97
GDL Reference Guide 9.0 (INT) p. 94
GDL Reference Guide 10.0 (INT) p. 93
GDL Reference Guide 11.0 (INT) p. 93